@echo off

cls 

:: IE-SPYAD Install/Uninstall Utility
::
:: Created by Eric L. Howes
::            eburger68@myrealbox.com
::            https://netfiles.uiuc.edu/ehowes/www/resource.htm
::
:: Copyright (c) 2000-2005 Eric L. Howes
::
:: This program is free software; you can redistribute it and/or modify it under
:: the terms of the GNU General Public License as published by the Free Software
:: Foundation; either version 2, or (at your option) any later version.
::
:: This program is distributed in the hope that it will be useful, but WITHOUT ANY
:: WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
:: A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
::
:: Some files distributed with this package may not be covered by the GNU GPL. Those
:: files remain the property of their original owners and are covered by the licenses
:: under which they were originally distributed.
::
:: All trademarks are the property of their respective owners.
::
:: You should have received a copy of the GNU General Public License along with this
:: program; see the file COPYING.  If not, write to the Free Software Foundation,
:: 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

::********************************************************************
::CHOICE Installation
::********************************************************************

:: Check for NT or 9x
if exist %WINDIR%\SYSTEM32\CONFIG goto prep-nt

:: ---------------
:: Copy choice.com
:: ---------------
:prep-9x

if exist %WINDIR%\command\choice.com goto MENU
if exist %WINDIR%\choice.com goto MENU

copy choice\choice.com %WINDIR%

goto MENU

:: ---------------
:: Copy choice.exe
:: ---------------
:prep-nt

if exist %WINDIR%\command\choice.exe goto MENU
if exist %WINDIR%\choice.exe goto MENU

copy choice\choice.exe %WINDIR%

goto MENU

::********************************************************************
:MENU
::********************************************************************

cls

:: -------------------------------
:: Give the main menu with choices
:: -------------------------------

echo               ----------------------------------
echo               IE-SPYAD Install/Uninstall Utility
echo               ----------------------------------
echo.
echo    [1] UNINSTALL the Currently Loaded IE-SPYAD List *
echo          Uninstall the currently loaded IE-SPYAD list of Restricted sites.
echo          This is recommended before installing a new version of IE-SPYAD.
echo.
echo          * Note: this will uninstall both the latest version of IE-SPYAD
echo                  as well as all previous versions.
echo.
echo    [2] INSTALL the New IE-SPYAD List
echo          Install the new IE-SPYAD list of Restricted sites.
echo.
echo    [3] REMOVE the Old Porn Site Domains
echo          Remove the 930+ porn domains that were dropped on 26 April 2003.
echo.
echo    [4] ADD the Old Porn Site Domains
echo          Add the 930+ porn domains that were dropped on 26 April 2003.         
echo.
echo    [5] Exit
echo.

:: ----------
:: Get choice
:: ----------

echo    What do you want to do?

choice /c:123456 /n /t:6,90 

if errorlevel 6 goto MENU
if errorlevel 5 goto FIN
if errorlevel 4 goto ADD
if errorlevel 3 goto REMOVE
if errorlevel 2 goto INSTALL
if errorlevel 1 goto UNINST

goto MENU

::********************************************************************
:UNINST
::********************************************************************

cls

:: -----------------
:: Confirm Uninstall
:: -----------------

   echo.
   echo                    ** CONFIRM UNINSTALL **
   echo. 
   echo.
   echo    This will uninstall the currently loaded IE-SPYAD
   echo    list of Restricted sites.
   echo.
   echo    Are you sure that you want to uninstall IE-SPYAD? 
   echo. 
   echo       [1] YES - uninstall IE-SPYAD
   echo       [2] NO  - return to main menu

   choice /c:123 /n /t:3,90

   if errorlevel 3 goto UNINST
   if errorlevel 2 goto MENU
   if errorlevel 1 goto GO-UNINST

goto UNINST

::--------
:GO-UNINST
::--------

cls

:: ----------------------
:: Check for proper files
:: ----------------------

if exist ie-ads-uninst.reg goto un-iespy

goto NO-FILE

:: ------------------
:: Uninstall IE-SPYAD
:: ------------------
:un-iespy

   echo.
   echo    You have chosen to uninstall IE-SPYAD...
   echo.
   start /w regedit.exe /s ie-ads-uninst.reg

goto SUCCESS

::********************************************************************
:INSTALL
::********************************************************************

cls

:: -----------------
:: Confirm Install
:: -----------------

   echo.
   echo                    ** CONFIRM INSTALL **
   echo. 
   echo.
   echo    This will install the IE-SPYAD list of Restricted sites.
   echo.
   echo    Note: it is recommended that you UNINSTALL previous versions
   echo    of IE-SPYAD before loading a new version of IE-SPYAD. You can
   echo    do so from the main menu.
   echo.
   echo    Are you sure that you want to install IE-SPYAD? 
   echo. 
   echo       [1] YES - install IE-SPYAD
   echo       [2] NO  - return to main menu

   choice /c:123 /n /t:3,90

   if errorlevel 3 goto INSTALL
   if errorlevel 2 goto MENU
   if errorlevel 1 goto GO-INSTALL

goto INSTALL

::---------
:GO-INSTALL
::---------

cls

:: ----------------------
:: Check for proper files
:: ----------------------

if exist ie-ads.reg goto in-iespy

goto NO-FILE

:: ------------------
:: Install IE-SPYAD
:: ------------------
:in-iespy

   echo.
   echo    You have chosen to install IE-SPYAD...
   echo.
   start /w regedit.exe /s ie-ads.reg

goto SUCCESS

::********************************************************************
:REMOVE
::********************************************************************

cls

:: --------------------------
:: Confirm Porn Sites Removal
:: --------------------------

   echo.
   echo                 ** CONFIRM PORN SITES REMOVAL **
   echo. 
   echo.
   echo    This will remove the 930+ porn domains that were dropped on 
   echo    26 April 2003 from your Restricted sites zone.
   echo.
   echo    Note: for more information on these porn sites and why they
   echo    were dropped from IE-SPYAD, see the file ADULT-NOTE.TXT in
   echo    the \ADULT directory.
   echo.
   echo    Are you sure that you want to remove those porn sites? 
   echo. 
   echo       [1] YES - remove the porn sites.
   echo       [2] NO  - return to main menu

   choice /c:123 /n /t:3,90

   if errorlevel 3 goto REMOVE
   if errorlevel 2 goto MENU
   if errorlevel 1 goto GO-REMOVE

goto REMOVE

::---------
:GO-REMOVE
::---------

cls

:: ----------------------
:: Check for proper files
:: ----------------------

if exist adult\adult-uninst.reg goto rm-porn

goto NO-FILE

:: -----------------
:: Remove Porn Sites
:: -----------------
:rm-porn

   echo.
   echo    You have chosen to remove the porn sites...
   echo.
   start /w regedit.exe /s adult\adult-uninst.reg

goto SUCCESS

::********************************************************************
:ADD
::********************************************************************

cls

:: ----------------------
:: Confirm Porn Sites Add
:: ----------------------

   echo.
   echo                 ** CONFIRM PORN SITES ADD **
   echo. 
   echo.
   echo    This will add the 930+ porn domains that were dropped on 
   echo    26 April 2003 to your Restricted sites zone.
   echo.
   echo    Note: for more information on these porn sites and why they
   echo    were dropped from IE-SPYAD, see the file ADULT-NOTE.TXT in
   echo    the \ADULT directory.
   echo.
   echo    Are you sure that you want to add those porn sites? 
   echo. 
   echo       [1] YES - add the porn sites.
   echo       [2] NO  - return to main menu

   choice /c:123 /n /t:3,90

   if errorlevel 3 goto ADD
   if errorlevel 2 goto MENU
   if errorlevel 1 goto GO-ADD

goto ADD

::---------
:GO-ADD
::---------

cls

:: ----------------------
:: Check for proper files
:: ----------------------

if exist adult\adult.reg goto ad-porn

goto NO-FILE

:: --------------
:: Add Porn Sites
:: --------------
:ad-porn

   echo.
   echo    You have chosen to add the porn sites...
   echo.
   start /w regedit.exe /s adult\adult.reg

goto SUCCESS

::********************************************************************
:NO-FILE
::********************************************************************

   echo.
   echo.
   echo    ...but a required file could not be found.
   echo.
   echo    Please correct this problem and try again.
   echo.
   pause (Press Any Key to Return to Main Menu)
   goto MENU

::********************************************************************
:ERROR
::********************************************************************

     echo.
     echo.
     echo    An error ocurred while performing this task...
     echo.
     echo.
     pause
     goto RETURN

::********************************************************************
:SUCCESS
::********************************************************************
  
     echo.
     echo.
     echo    SUCCESS!!
     echo.
     echo.
     pause
     goto RETURN

::********************************************************************
:RETURN
::********************************************************************

cls

:: -----------------
:: Give Choice Again
:: -----------------

   echo.
   echo.
   echo    What Do You Want to Do Now?
   echo.
   echo    [1] Return to Main Menu
   echo    [2] Exit
   echo.

   choice /c:123 /n /t:3,90

   if errorlevel 3 goto return
   if errorlevel 2 goto fin
   if errorlevel 1 goto menu

::********************************************************************
:FIN
::********************************************************************

   cls

   echo.
   echo.
   echo    You have chosen to EXIT the IE-SPYAD Install/Uninstall Utility.
   echo.
   echo.
   echo    Bye for now...
   echo.
   echo.
